home *** CD-ROM | disk | FTP | other *** search
/ BlastDOS / [DOS Application] Microsoft - LAN Manager 2.2c - Installation Disks.zip / NW / NWLOAD.BAT < prev    next >
DOS Batch File  |  1994-09-02  |  2KB  |  58 lines
  1. @echo off
  2. rem *************************************************************************
  3. rem **    IPXMARK return value is 1 on error, 2 for already loaded condition.
  4. rem *************************************************************************
  5. echo Loading IPX protocol and Netware shell.
  6. load ipx
  7. if errorlevel 1 goto ERROR_LOADING
  8. rem *************************************************************************
  9. rem **    To invoke the DOS version independent NetWare shell, uncomment
  10. rem **    the following two lines.
  11. rem netx
  12. rem goto LOGIN
  13. rem **    End of DOS version independent NetWare shell lines
  14. rem *************************************************************************
  15. rem **    DOSVER return value is 1 on error (and DOS versions below 3.x),
  16. rem **    DOS version otherwise.
  17. rem *************************************************************************
  18. dosver
  19. if errorlevel 5 goto DOS5x
  20. if errorlevel 4 goto DOS4x
  21. if errorlevel 3 goto DOS3x
  22. goto ERROR_LOADING
  23. :DOS3x
  24. net3
  25. goto LOGIN
  26. :DOS4x
  27. net4
  28. goto LOGIN
  29. :DOS5x
  30. net5
  31. :LOGIN
  32. echo.
  33. echo Log in to the NetWare Server.
  34. echo Type NWUNLOAD when you wish to unload NetWare.
  35. @echo on
  36. q:login %1
  37. @echo off
  38. echo.
  39. rem *************************************************************************
  40. rem **    Ensure that the entries in the PATH environment variable when IPXMARK
  41. rem **    was run are still in the PATH environment variable after logging in
  42. rem **    to the NetWare server.
  43. rem **    The path to FIXPATH.EXE is explicitly specified because the NetWare
  44. rem **    login may have removed the NETPROG directory from the path.
  45. rem **    If the installer default for the NETPROG directory does not contain
  46. rem **    FIXPATH.EXE, generate message so that the user knows to edit the
  47. rem **    following lines for the correct path.
  48. rem *************************************************************************
  49. if not exist c:\lanman.dos\netprog\fixpath.exe goto ERROR_FIXPATH
  50. c:\lanman.dos\netprog\fixpath.exe
  51. goto END
  52. :ERROR_FIXPATH
  53. echo Please edit NWLOAD.BAT to run FIXPATH as described in NWLOAD.BAT.
  54. goto END
  55. :ERROR_LOADING
  56. echo          NetWare load failed.
  57. :END
  58.